用dos命令实现导入、导出windows计划任务详解

  • Z时代
  • 2024-01-10
  • 分类：综合

新手指南

要把公司软件用的计划任务用命令行批处理的方式导入一个新的系统里，所有通过查资料，一个可以用来导出和导入的脚本。

导出用法为：脚本名称+空格+export

导入用法为：脚本名称+空格+import

以下为内容和注释：


rem 以下为关闭命令打印
@echo off
rem 以下为清屏
cls
rem 以下为设置此批处理所有的环境变量只应用于当前批处理
setlocal EnableDelayedExpansion
rem 以下为设置变量
set runasUsername=domain\administrator
set runasPassword=password
rem 以下%1是在此批处理执行时后面的第一个命令行参数（在执行的格式：脚本名+export 就相当于跳转到”：export“）
if %1. == export. call :export
if %1. == import. call :import
rem 以下为退出当前脚本，不是退出整个批处理
exit /b 0
:export
rem 以下为创建一个tasks文件夹，所有的错误不显示
md tasks 2>nul
rem 以下为列出所有计划任务并指定csv格式，然后找出与字符串TaskName不匹配的行，输出到一个文本文件
schtasks /query /fo csv | findstr /V /c:"TaskName" > tnlist.txt
rem 循环查找以（,）为分隔符列出每一行的每一项，指定%%i为第一项，用tokens=1,2指定第二项%%j和第三项%%k（也可以
rem 指定%%t为第一项，那么tokens=1,2指定第二项%%u和第三项%%v，第四项为%%W）
for /F "delims=, tokens=1,2*" %%i in (tnlist.txt) do (
 echo %%i
 echo %%j
 echo %%k
 set tn=%%i
rem 以下为设置fn为把tn的内容里的\替换成#
 set fn=!tn:\=#!
 echo !tn!
 echo !fn!
rem 以下为列出所有计划任务并指定xml格式，输出到当前目录的tasks文件夹下的XXX.xml文件
 schtasks /query /xml /TN !tn! > tasks\!fn!.xml
)
rem 删除所有windows自带的计划任务
del tasks\#Microsoft*.xml
exit /b 0
rem 以下为导入标签，在执行的格式：脚本名+import 将会直接跳转到这里开始执行
:import
rem 在这个目录里循环找到所有的xml
for %%f in (tasks\*.xml) do (
  rem 用call命令来调用（:importfile）标签执行，并赋予上面查找出来的名字为参数
  call :importfile "%%f"
)
exit /b 0
:importfile
rem 以下为设置filename=上面用call命令调用时赋予的第一个参数，如果是 set filename=%2则是第二个参数     
set filename=%1
rem 以下为设置把filename里#字符替换为空
set taskname=%filename:#=%
rem 以下为设置把filename里tasks\字符替换为空
set taskname=%taskname:tasks\=%
rem 以下为设置把filename里.xml字符替换为空
set taskname=%taskname:.xml=%
rem 以下为用用户名和密码创建名字为XXX的计划认为，以xml文件为参数
schtasks /create /ru %runasUsername% /rp %runasPassword% /tn %taskname% /xml %filename% 
echo on

结束

这样就可以导出所有不是系统自带的计划任务和导入现有的xml格式的计划任务了

以上是 用dos命令实现导入、导出windows计划任务详解 的全部内容， 来源链接： utcz.com/z/334093.html

回到顶部